Santosh Kumar

 
Reading text from different files format may give directions to most of the challenges faced for building various tools like site search engine. Once you are able to extract texts, coding of very simple logic will be sufficient to design hundreds of web and window based tools. Here in this article, I am using itextsharp.dll apart from .NET and COM libraries. 
 
You need the following binaries. iTextSharp is a free binary. All other are from Miscrosoft and should be used as per Miscrosoft guidelines. If you have MS Office installed in you system you don't need these binaries. You can simply add COM reference of MS Word and MS Excel object libraries.
  
Interop.Excel.dll for .Net 2.0
(download attachment | download from original link)
 
Interop.Word.dll for .Net 2.0
(download attachment | download from original link)
 
Interop.Office.dll for .Net 2.0
(download attachment | download from original link)
 
Interop.VBIDE.dll for .Net 2.0
(download attachment | download from original link)
 
iTextSharp for .Net 2.0
(download attachment | download from original link)
 
'''''Code Begins herefrom 
 
Imports System.IO
Imports System.Data
Imports System.Xml
Imports System.Text
Imports System.Diagnostics
Imports Microsoft.VisualBasic
Imports System.Text.RegularExpressions
Imports iTextSharp.text.pdf
Imports System.Windows.Forms
 
Public Function ReadText_TXT(ByVal faPath As String) As String
    Dim vRet As String = ""
    Dim vStreamReader As StreamReader = File.OpenText(faPath)
    Try
        vRet = vStreamReader.ReadToEnd()
        vStreamReader.Close()
    Catch ex As Exception
        vRet = ""
    End Try
    Return vRet
End Function
 
Public Function ReadText_DOC(ByVal faPath As String) As String
    Dim vRet As String = ""
    Dim vRTB As New RichTextBox
    Dim vWD As New Word.Application
    vWD.Documents.Open(faPath)
    vWD.Selection.WholeStory()
    vWD.Selection.Copy()
    vRTB.Paste()
    vRet = vRTB.Text
    vWD.Quit()
    DoGarbageCollection(vWD)
    Return vRet
End Function
 
Public Function ReadText_XLS(ByVal faPath As String) As String
    Dim vRet As String = ""
    Dim vRTB As New RichTextBox
    Dim vXL As New Excel.Application
    Dim vWB As Excel.Workbook = Nothing
    Dim vWS As Excel.Worksheet = Nothing
    Dim vUR As Excel.Range = Nothing
    Dim vCnt As Integer
    Dim vCtr As Integer
    Dim vRow As Integer
    Dim vCol As Integer
    Dim vRows As Integer
    Dim vCols As Integer
    vWB = vXL.Workbooks.Open(faPath)
    vXL.Calculation = Excel.XlCalculation.xlCalculationManual
    vXL.AlertBeforeOverwriting = False
    vCnt = vWB.Worksheets.Count
 
    For vCtr = 1 To vCnt
        vWS = vWB.Worksheets(vCtr)
        vUR = vWS.UsedRange
        vRows = vUR.Rows.Count
        vCols = vUR.Columns.Count
        For vRow = 1 To vRows
            For vCol = 1 To vCols
                vRet = vRet & CType(vUR.Cells(vRow, vCol), Excel.Range).Value & " "
            Next vCol
        Next vRow
    Next
 
    vWB.Close(False)
    DoGarbageCollection(vWB)
    vXL.Quit()
    DoGarbageCollection(vXL)
 
    Return vRet
End Function
 
Public Function ReadText_PDF(ByVal faPath As String, Optional ByVal faFromPageNum As Integer = 0, _
    Optional ByVal faUptoPageNum As Integer = 0) As String
    Dim sb As New System.Text.StringBuilder()
    Try
        Dim reader As New PdfReader(faPath)
        Dim pageBytes() As Byte = Nothing
        Dim token As PRTokeniser = Nothing
        Dim tknType As Integer = -1
        Dim tknValue As String = String.Empty
        If faFromPageNum = 0 Then
            faFromPageNum = 1
        End If
        If faUptoPageNum = 0 Then
            faUptoPageNum = reader.NumberOfPages
        End If
        If faFromPageNum > faUptoPageNum Then
            Throw New ApplicationException("Err: faFromPageNum > faUptoPageNum")
        End If
 
        For i As Integer = faFromPageNum To faUptoPageNum Step 1
            pageBytes = reader.GetPageContent(i)
            If Not IsNothing(pageBytes) Then
                token = New PRTokeniser(pageBytes)
                While token.NextToken()
                    tknType = token.TokenType()
                    tknValue = token.StringValue
                    If tknType = PRTokeniser.TK_STRING Then
                        sb.Append(token.StringValue)
                    ElseIf tknType = 1 AndAlso tknValue = "-600" Then
                        sb.Append(" ")
                    ElseIf tknType = 10 AndAlso tknValue = "TJ" Then
                        sb.Append(" ")
                    End If
                    Application.DoEvents()
                End While
            End If
        Next i
        sb = New StringBuilder(sb.ToString)
    Catch ex As Exception
        Return String.Empty
 
    End Try
    Return sb.ToString()
End Function
 
Public Function ReadText_WEB(ByVal faUrl As String) As String
    Dim vRet As String = ""
    Try
        Dim vSNWebClient As System.Net.WebClient
        Dim vUTF8Encoding As UTF8Encoding
        vSNWebClient = New System.Net.WebClient()
        vUTF8Encoding = New UTF8Encoding()
        vRet = vUTF8Encoding.GetString(vSNWebClient.DownloadData(faUrl))
    Catch ex As Exception
        vRet = ""
    End Try
    Return ReadText_HTM(vRet)
End Function
 
Private Sub DoGarbageCollection(ByVal faObj As Object)
    Try
        Runtime.InteropServices.Marshal.ReleaseComObject(faObj)
    Catch
    Finally
        faObj = Nothing
    End Try
End Sub
 
Private Function ReadText_HTM(ByVal faContent As String) As String
    Dim vRet As String = faContent
    Try
        Dim vRegEx As Regex
        vRegEx = New Regex("", RegexOptions.IgnoreCase)
        vRet = Regex.Replace(vRet, "<(select|option|script|style|title)(.*?)>((.|\n)*?)</(select|option|script|style|title)>", " ", RegexOptions.IgnoreCase)
        vRet = Regex.Replace(vRet, "&(nbsp|quot|copy);", "")
        vRet = Regex.Replace(vRet, "<([\s\S])+?>", " ", RegexOptions.IgnoreCase)
        vRet = Regex.Replace(vRet, "\W", " ")
    Catch ex As Exception
        vRet = ""
    End Try
    Return Trim(vRet)
End Function